用户登录
用户注册

分享至

用bat实现的自动关机的代码

  • 作者: 别吵吵吻我
  • 来源: 51数据库
  • 2021-09-03

一般情况下我们都是使用shutdown来实现关机与重启

用法: shutdown [/i | /l | /s | /r | /a | /p | /h | /e] [/f]
[/m \\computer][/t xxx][/d [p:]xx:yy [/c "comment"]]

没有参数 显示帮助。这与键入 /? 是一样的
/? 显示帮助。这与不键入任何选项是一样的
/i 显示图形用户界面(gui)。
这必须是第一个选项
/l 注销。这不能与 /m 或 /d 选项一起使用
/s 关闭计算机
/r 关闭并重启动计算机
/a 放弃系统关闭。
这只能在超时过程中使用
/p 关闭本地计算机,没有超时或警告。
这只能与 /d 选项一起使用
/h 休眠本地计算机。
这只能与 /f 选项一起使用
/e 将计算机的意外关闭原因记入文档
/m \\computer 指定目标计算机
/t xxx 设置关闭前的超时为 xxx 秒。
有效范围是 0-600,默认为 30
/c "comment" 重启动或关闭的原因的注释。
最大允许 127 个字符
/f 强制正在运行的应用程序关闭而不事先警告用户
/d [p:]xx:yy 提供重启动或关闭的原因
p 表明重启动或关闭是计划内的
xx 是主要原因号(小于 256 的正整数)
yy 是次要原因号(小于 65536 的正整数)

重启
shutdown /r /f

关机
shutdown /s /f

先来个简单功能版本的

复制代码 代码如下:

@echo off
mode con lines=25
title 定时关机
color 1f
cls
echo.
echo.
echo.
echo.
echo              时间使用24小时制(如2:15、12:00),可以输入多个时间点
echo.
echo                           多个时间点用空格分隔
echo.
echo.
echo ━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━
echo.
set times=
set /p times=                     请输入关机时间:
:: 以下语句实现每个星期的每一天指定时间关机
:: 如果要换成每个月的某几天,请改字母为数字,并用逗号分隔
:: 以下代码没有错误检测语句,输入时间的时候务必按照指定格式输入
:: 可以用在cmd窗口用at命令来查看计划任务
if not "%times%"=="" for %%i in (%times%) do (
    at %%i /every:m,t,w,th,f,s,su shutdown -s
)


下面是多功能版的,适合学习bat的朋友
复制代码 代码如下:

@echo off
title 自动关机程序 作者:廖晓青
:start
cls
color 1f
rem 使用color命令对控制台输出颜色进行更改
mode con: cols=41 lines=18
rem mode语句为设定窗体的宽和高
set tm1=%time:~0,2%
set tm2=%time:~3,2%
set tm3=%time:~6,2%
echo %date% %tm1%点%tm2%分%tm3%秒
echo =========================================
echo 请选择要进行的操作,然后按回车
echo ───────────────
echo.
echo 1. 定时关机
echo 2. 倒计时关机
echo 3. 删除定时关机任务
echo 4. 查看任务状态
echo 5. 刷新当前时间
echo 6. 重新启动
echo 7. 锁定计算机
echo 8. 注销
echo 9. 退出
echo.

:cho
set choice=
set /p choice=选择:
rem 设定变量"choice"为用户输入的字符
if not "%choice%"=="" set choice=%choice:~0,1%
rem 如果输入大于1位,取第1位,比如输入132,则返回值为1
echo.
if /i "%choice%"=="1" goto sethour
if /i "%choice%"=="2" goto outtime
if /i "%choice%"=="3" goto delat
if /i "%choice%"=="4" goto view
if /i "%choice%"=="5" goto start
if /i "%choice%"=="6" goto restart
if /i "%choice%"=="7" goto lock
if /i "%choice%"=="8" goto logoff
if /i "%choice%"=="9" goto end
rem 为避免出现返回值为空或含空格而导致程序异常,需在变量外另加双引号
rem 注意,if语句需要双等于号
rem 如果输入的字符不是以上数字,将返回重新输入
echo 选择无效,请重新输入
echo.
goto cho

:sethour
cls
echo.
set ask=
set /p ask=是否设定为每天执行关机命令(y/n):
if not "%ask%"=="" set ask=%ask:~0,1%
if /i "%ask%"=="y" goto yes
if /i "%ask%"=="n" goto no
goto sethour

:yes
echo 请指定24小时制式时间,格式为 小时:分钟
set shutdowntime=
set /p shutdowntime=输入:
at %shutdowntime% /every:m,t,w,th,f,s,su tsshutdn 0 /delay:0 /powerdown >nul
rem 设定为每周的星期一至星期日,即为每天
if not errorlevel 1 goto ok
rem 如果输入正确,就执行ok段的语句
echo %shutdowntime% 不是标准的时间格式,请重新输入
echo.
goto yes

:no
echo 请指定24小时制式时间,格式为 小时:分钟
set shutdowntime=
set /p shutdowntime=输入:
at %shutdowntime% tsshutdn 0 /delay:0 /powerdown >nul
if not errorlevel 1 goto ok
echo %shutdowntime% 不是标准的时间格式,请重新输入
echo.
goto no

:ok
echo.
set h=%shutdowntime:~1,1%
set ah=%shutdowntime:~0,1%
set am=%shutdowntime:~2,2%
set bh=%shutdowntime:~0,2%
set bm=%shutdowntime:~3,2%
if "%h%"==":" (
set hm=%ah%时%am%分
) else (
set hm=%bh%时%bm%分)
rem 如果输入h:mm则hm=h时mm分,否则hm=hh时mm分
if /i "%ask%"=="y" echo 系统将于每天的%hm%关闭
if /i "%ask%"=="n" echo 系统将于%hm%关闭
echo 设定完毕! 按任意键继续...
pause >nul
goto start

:outtime
cls
echo.
echo 请输入倒计时秒数
echo ────────
echo (设定后要取消,单击"确定"后按ctrl+c键两次)
set timed=
set /p timed=输入:
tsshutdn %timed% /delay:0 /powerdown >nul
if not errorlevel 1 goto ok
echo %timed% 是无效的关机时间,请重新输入
echo.
goto outtime

:delat
cls
echo.
at /del /y
echo 定时关机任务已取消,按任意键继续...
pause >nul
goto start

:view
mode con: cols=85 lines=18
color 70
echo.
at
echo 按任意键继续...
pause >nul
goto start

:restart
shutdown -r -t 0

:lock
rundll32.exe user32.dll,lockworkstation
goto start

:logoff
logoff

:end
exit

软件
前端设计
程序设计
Java相关